Lege med mobiltelefon farvedisplay

Do you have a question? Post it now! No Registration Necessary

Translate This Thread From Danish to

Threaded View
Hey.

Er der ikke nogen der har prøvet at pjatte lidt med de små farveskærme fra
mobiltelefoner? Jeg har scoret en lille kvadratisk en fra en Nokia (vist en
3200), tror den er 128x128 pixels. Den har et lille 10-polet stik der sidder
for oven til højre. Bag på står der: UG13D01AA S3 11 15 * #

Tænker på at sætte det til en Atmel og lege lidt.  :-)  Nogen der kender
benforbindelserne, eller links til nogle projekter eller datablad?

--
Ulrik Smed
Aarhus, Denmark



Re: Lege med mobiltelefon farvedisplay
Hej
Quoted text here. Click to load it

For ikke så længe siden, var der en her i gruppen, der forespurgte om samkøb
af disse display, netop til hjemmefusk.
Prøv at kikke nok et par måneder tilbage, der var også en link til datablade
+ diverse.

Mvh Hauge



Re: Lege med mobiltelefon farvedisplay

Quoted text here. Click to load it

http://www.microsyl.com /

Han har lavet noget med nogle nokia display, men er ikke sikker på det er
farve

Kasper



Re: Lege med mobiltelefon farvedisplay

Quoted text here. Click to load it

Hm, det ser lidt sort/hvidt ud, synes jeg.  ;-)  Men hans propeller-clock er
fed! :-)

Jeg har prøvet at kigge lidt tilbage i gruppen, men synes ikke lige jeg kan
finde noget.

--
Ulrik Smed
Aarhus, Denmark



Re: Lege med mobiltelefon farvedisplay
Quoted text here. Click to load it

Jeg har den mærket (paste't herunder)- men fik ikke gjort noget ved det. Jeg
er dog stadig på udkig efter små billige paneler (der ikke kun kan skaffes
"een gang")... Så lad os endelig hører om resultaterne! =)

Mvh.
 Anders


Quoted text here. Click to load it






















Re: Lege med mobiltelefon farvedisplay

Quoted text here. Click to load it

Ahh, det var i markedsgruppen, troede det var her.  :-)  Men fedt, der er
datablade på Philips og Epson, det må være et Epson jeg har. Jeg kan se det
kører serielt med enten 3 eller 4 ledninger. Controlleren kan også kører
parallelt, men ledningerne til det er ikke ført ud på de her displays. Man
kan ikke læse display RAM'en i seriel mode, så man må holde en kopi i sin
egen RAM hvis man vil lave transparente menu'er og den slags blær.  ;-)

Takker for linket, det var kanon! Skal nok larme op hvis jeg får gang i det!
:-)

--
Ulrik Smed
Aarhus, Denmark



Re: Lege med mobiltelefon farvedisplay

Quoted text here. Click to load it

Hedder det ikke når du får gang i det ? ;-)

--
  Med venlig hilsen,    Ove Kjeldgaard,    nospam AT privat DOT dk
  Natur og Friluftsliv: <http://hiker.dk

Re: Lege med mobiltelefon farvedisplay
Quoted text here. Click to load it

Hehe, johh forhåbentlig!  ;-)  Der er jo bare lige et forår 'i vejen' for
tiden, jeg kan osse godt finde på at dyrke lidt natur og friluftsliv ind
imellem, selvom det bliver til for lidt.  :-)

Har lige siddet og læst i databladet til Epson'en, og resten af den tråd på
det LCD-forum, og blev da lidt klogere og lidt mere ivrig for at komme
igang.

--
Ulrik Smed
Aarhus, Denmark



Re: Lege med mobiltelefon farvedisplay


Quoted text here. Click to load it

He..He

Håbede nu at der var nogen som ville have svaret på min post i
"marked"

Hilsen
Carsten


Re: Lege med mobiltelefon farvedisplay
Weee, sE5% lykkes det sQ!  :-D
http://home19.inet.tele.dk/ulsm/Display/DSC0001.jpg
http://home19.inet.tele.dk/ulsm/Display/DSC0003.jpg

Det viste sig at det faktisk er et Philips display jeg har, jeg ku'
f2E%..
ikke fE5% de kommandoer til at virke som var i Epson databladet. Det var
der
altsE5% en go' grund til!  ;-)  Men totalt sjovt lille display, 130x130
pixels, i 4096 farver. Det ser en del bedre ud i virkeligheden end pE5%
de her
halvdE5%rlige billeder!


Re: Lege med mobiltelefon farvedisplay
Hejsa

Jeg har selv nogle af de lcd's til at ligge. Kan du ik smdie mig koden til
det? Jeg har bøvlet med det. og kan ik få liv i lortet.

MVH
René

rene bindestreg snipped-for-privacy@get2net.dk
Weee, så lykkes det sQ!  :-D
http://home19.inet.tele.dk/ulsm/Display/DSC0001.jpg
http://home19.inet.tele.dk/ulsm/Display/DSC0003.jpg

Det viste sig at det faktisk er et Philips display jeg har, jeg ku'
f...
ikke få de kommandoer til at virke som var i Epson databladet. Det var
der
altså en go' grund til!  ;-)  Men totalt sjovt lille display, 130x130
pixels, i 4096 farver. Det ser en del bedre ud i virkeligheden end på
de her
halvdårlige billeder!



Re: Lege med mobiltelefon farvedisplay
Quoted text here. Click to load it

Hey!

Har du styr på hvordan benene skal forbindes? De sidder sådan her, set fra
forsiden af displayet:

1   10
2   9
3   8
4   7
5   6

Her er et stykke kode der burde give et mønster af skrå farvestriber der
kører hen over skærmen. Der kører på en 8515 på 4MHz, og 3.3V. De 3.3V er
vigtige, da displayet også kører 3.3V, og ikke må få 5V på indgangene.
"sendtodisplay" er lavet uden loop, for at få hastigheden op.

;Pin
;1   Vdigital       2,7V - 3,3V
;2   RESET          LCD_RESET, user defined
;3   SDATA          LCD_SDA, SPI MOSI
;4   SCLK           LCD_CLK, SPI CLK
;5   ~CS            LCD_CS, user defined
;6   Vdisplay       2,7V - 3,3V
;7   n/c
;8   GND            GND
;9   LED-           GND or -3.2V
;10  LED+           +6.4V or +3.2V, 15 - 30mA

.include "8515def.inc"

;init stack pointer
ldi r16,low(ramend)
out spl,r16
ldi r16,high(ramend)
out sph,r16

rcall initdisplay
rcall set8bitmode

ldi r16,0x2c ; write
rcall senddisplaycommand

main:
inc r19
mov r16,r19
rcall senddisplaydata
rjmp main

pause:
push r16
push r17
push r18
ldi r16,0
ldi r17,10
ldi r18,1
pl1:
 dec r16
brne pl1
 dec r17
brne pl1
 dec r18
brne pl1
pop r18
pop r17
pop r16
ret

set8bitmode:
ldi r16,0x3a ; color mode
rcall senddisplaycommand
ldi r16,0x2 ; 8 bit mode
rcall senddisplaydata
ldi r16,0x2d ; set palette
rcall senddisplaycommand
ldi r19,20 ; loop
ldi zl,low(palettetable*2)
ldi zh,high(palettetable*2)
s8bmloop:
 lpm
 adiw zl,1
 mov r16,r0
 rcall senddisplaydata
 dec r19
brne s8bmloop
ret

palettetable:
; red
.db 0,1,3,5,7,9,12,15
; green
.db 0,1,3,5,7,9,12,15
; blue
.db 0,3,9,15

initdisplay:
rcall initdisplayport
; display on
ldi r16,0x29
rcall senddisplaycommand
; sleep out
ldi r16,0x11
rcall senddisplaycommand
ret


; display control

.set csbit=6
.set databit=5
.set clockbit=7
.set resetbit=4

.set displayportdir=ddra
.set displayport=porta

initdisplayport:
sbi displayportdir,csbit
sbi displayportdir,databit
sbi displayportdir,clockbit
sbi displayportdir,resetbit
sbi displayport,csbit
sbi displayport,clockbit
cbi displayport,resetbit
rcall pause
sbi displayport,resetbit
ret

senddisplaycommand: ; r16=command
cbi displayport,csbit ; cs low
; send command/databit
cbi displayport,databit ; data low
rjmp sendtodisplay

senddisplaydata: ; r16=data
cbi displayport,csbit ; cs low
; send command/databit
sbi displayport,databit ; data high

sendtodisplay:
in r17,displayport
cbr r17,exp2(databit)+exp2(clockbit)
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,7
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,6
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,5
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,4
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,3
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,2
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,1
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbrc r16,0
 sbi displayport,databit ; data high
sbi displayport,clockbit ; clock high
out displayport,r17 ; clock and data low
sbi displayport,csbit ; cs high
ret

.dseg
.org 0x60
rndbytes:
.byte 6
spibyte:
.byte 1


--
Ulrik Smed
Aarhus, Denmark



Re: Lege med mobiltelefon farvedisplay
Hejsa

Ja jeg havde sat det rigtig sammen. men ja ingen held. men tak for koden så
kan jeg få det testet når jeg lige har tid ;)

René



Site Timeline